PL/SQL - 数组

在本章中，我们将讨论 PL/SQL 中的数组。 PL/SQL 编程语言提供了一种称为VARRAY 可变数组的数据结构，它可以存储相同类型元素的固定大小的顺序集合。 varray 可变数组用于存储有序的数据集合，但通常最好将数组视为相同类型变量的集合。

所有可变数组都由连续的内存位置组成。 最低地址对应于第一个元素，最高地址对应于最后一个元素。

数组是集合类型数据的一部分，它代表可变大小的数组。 我们将在后面的章节'PL/SQL Collections'中研究其他集合类型。

varray 中的每个元素都有一个与之关联的索引。 它还具有可以动态更改的最大大小。

创建 Varray 类型

可变数组类型是使用 CREATE TYPE 语句创建的。 您必须指定存储在可变数组中的元素的最大大小和类型。

在架构级别创建 VARRAY 类型的基本语法是 −

CREATE OR REPLACE TYPE varray_type_name IS VARRAY(n) of <element_type>

Where,

• varray_type_name 是一个有效的属性名称，
• n 是可变数组中的元素数（最大值），
• element_type 是数组元素的数据类型。

可以使用 ALTER TYPE 语句更改可变数组的最大大小。

例如，

CREATE Or REPLACE TYPE namearray AS VARRAY(3) OF VARCHAR2(10); 
/ 

Type created.

在 PL/SQL 块中创建 VARRAY 类型的基本语法是 −

TYPE varray_type_name IS VARRAY(n) of <element_type>

例如 −

TYPE namearray IS VARRAY(5) OF VARCHAR2(10); 
Type grades IS VARRAY(5) OF INTEGER;

现在让我们研究几个例子来理解这个概念 −

示例 1

以下程序说明了可变数组的使用 −

DECLARE 
   type namesarray IS VARRAY(5) OF VARCHAR2(10); 
   type grades IS VARRAY(5) OF INTEGER; 
   names namesarray; 
   marks grades; 
   total integer; 
BEGIN 
   names := namesarray('Kavita', 'Pritam', 'Ayan', 'Rishav', 'Aziz'); 
   marks:= grades(98, 97, 78, 87, 92); 
   total := names.count; 
   dbms_output.put_line('Total '|| total || ' Students'); 
   FOR i in 1 .. total LOOP 
      dbms_output.put_line('Student: ' || names(i) || ' 
      Marks: ' || marks(i)); 
   END LOOP; 
END; 
/

在 SQL 提示符下执行上述代码时，会产生以下结果 −

Total 5 Students 
Student: Kavita  Marks: 98 
Student: Pritam  Marks: 97 
Student: Ayan  Marks: 78 
Student: Rishav  Marks: 87 
Student: Aziz  Marks: 92 

PL/SQL procedure successfully completed. 

请注意 −

• 在 Oracle 环境中，可变数组的起始索引始终为 1。

• 您可以使用与 varray 同名的 varray 类型的构造方法来初始化 varray 元素。

• 可变数组是一维数组。

• 变量数组在声明时自动为 NULL，并且必须在其元素被引用之前对其进行初始化。

示例 2

可变数组的元素也可以是任何数据库表的 %ROWTYPE 或任何数据库表字段的 %TYPE。 下面的例子说明了这个概念。

我们将使用存储在数据库中的 CUSTOMERS 表作为 −

Select * from customers;  

+----+----------+-----+-----------+----------+ 
| ID | NAME     | AGE | ADDRESS   | SALARY   | 
+----+----------+-----+-----------+----------+ 
|  1 | Ramesh   |  32 | Ahmedabad |  2000.00 | 
|  2 | Khilan   |  25 | Delhi     |  1500.00 | 
|  3 | kaushik  |  23 | Kota      |  2000.00 | 
|  4 | Chaitali |  25 | Mumbai    |  6500.00 | 
|  5 | Hardik   |  27 | Bhopal    |  8500.00 | 
|  6 | Komal    |  22 | MP        |  4500.00 | 
+----+----------+-----+-----------+----------+ 

以下示例使用了 cursor，您将在单独的章节中详细学习。

DECLARE 
   CURSOR c_customers is 
   SELECT  name FROM customers; 
   type c_list is varray (6) of customers.name%type; 
   name_list c_list := c_list(); 
   counter integer :=0; 
BEGIN 
   FOR n IN c_customers LOOP 
      counter := counter + 1; 
      name_list.extend; 
      name_list(counter)  := n.name; 
      dbms_output.put_line('Customer('||counter ||'):'||name_list(counter)); 
   END LOOP; 
END; 
/ 

在 SQL 提示符下执行上述代码时，会产生以下结果 −

Customer(1): Ramesh  
Customer(2): Khilan  
Customer(3): kaushik     
Customer(4): Chaitali  
Customer(5): Hardik  
Customer(6): Komal  

PL/SQL procedure successfully completed.