VB.Net - 异常处理

异常是程序执行过程中出现的问题。 异常是对程序运行时出现的异常情况的响应，例如尝试除以零。

异常提供了一种将控制从程序的一个部分转移到另一个部分的方法。 VB.Net 异常处理基于四个关键字 - Try、Catch、Finally 和 Throw。

• Try − Try 块标识将激活特定异常的代码块。 其后跟随一个或多个 Catch 块。

• Catch − 程序使用异常处理程序在程序中要处理问题的位置捕获异常。 Catch 关键字表示捕获异常。

• Finally − Final 块用于执行一组给定的语句，无论是否抛出异常。 例如，如果打开一个文件，则无论是否引发异常，都必须关闭该文件。

• Throw − 当问题出现时，程序会抛出异常。 这是使用 Throw 关键字完成的。

语法

假设某个块将引发异常，则方法将使用 Try 和 Catch 关键字的组合来捕获异常。 Try/Catch 块放置在可能生成异常的代码周围。 Try/Catch 块中的代码称为受保护代码，使用 Try/Catch 的语法如下所示 −

Try
   [ tryStatements ]
   [ Exit Try ]
[ Catch [ exception [ As type ] ] [ When expression ]
   [ catchStatements ]
   [ Exit Try ] ]
[ Catch ... ]
[ Finally
   [ finallyStatements ] ]
End Try

您可以列出多个 catch 语句来捕获不同类型的异常，以防您的 try 块在不同情况下引发多个异常。

.Net Framework 中的异常类

在.Net Framework 中，异常由类表示。 .Net Framework中的异常类主要直接或间接派生自System.Exception类。 从 System.Exception 类派生的一些异常类是 System.ApplicationException 和 System.SystemException 类。

System.ApplicationException 类支持应用程序生成的异常。 所以程序员定义的异常应该从这个类派生。

System.SystemException类是所有预定义系统异常的基类。

下表提供了一些从 Sytem.SystemException 类派生的预定义异常类 −

处理异常

VB.Net 以 try 和 catch 块的形式为异常处理问题提供了结构化的解决方案。 使用这些块，核心程序语句与错误处理语句分开。

这些错误处理块是使用 Try、Catch 和 Finally 关键字实现的。 以下是发生除以零条件时抛出异常的示例 −

Module exceptionProg
   Sub division(ByVal num1 As Integer, ByVal num2 As Integer)
      Dim result As Integer
      Try
         result = num1 \ num2
      Catch e As DivideByZeroException
         Console.WriteLine("Exception caught: {0}", e)
      Finally
         Console.WriteLine("Result: {0}", result)
      End Try
   End Sub
   Sub Main()
      division(25, 0)
      Console.ReadKey()
  End Sub
End Module

当上面的代码被编译并执行时，会产生以下结果 −

Exception caught: System.DivideByZeroException: Attempted to divide by zero. 
at ...
Result: 0

创建用户定义的异常

您还可以定义自己的异常。 用户定义的异常类派生自 ApplicationException 类。 下面的例子演示了这一点 −

Module exceptionProg
   Public Class TempIsZeroException : Inherits ApplicationException
      Public Sub New(ByVal message As String)
         MyBase.New(message)
      End Sub
   End Class
   Public Class Temperature
      Dim temperature As Integer = 0
      Sub showTemp()
         If (temperature = 0) Then
            Throw (New TempIsZeroException("Zero Temperature found"))
         Else
            Console.WriteLine("Temperature: {0}", temperature)
         End If
      End Sub
   End Class
   Sub Main()
      Dim temp As Temperature = New Temperature()
      Try
         temp.showTemp()
      Catch e As TempIsZeroException
         Console.WriteLine("TempIsZeroException: {0}", e.Message)
      End Try
      Console.ReadKey()
   End Sub
End Module

当上面的代码被编译并执行时，会产生以下结果 −

TempIsZeroException: Zero Temperature found

Throwing 对象

如果对象直接或间接派生自 System.Exception 类，则可以抛出该对象。

您可以在 catch 块中使用 throw 语句将当前对象抛出为 −

Throw [ expression ]

下面的程序演示了这一点 −

Module exceptionProg
   Sub Main()
      Try
         Throw New ApplicationException("A custom exception _ is being thrown here...")
      Catch e As Exception
         Console.WriteLine(e.Message)
      Finally
         Console.WriteLine("Now inside the Finally Block")
      End Try
      Console.ReadKey()
   End Sub
End Module

当上面的代码被编译并执行时，会产生以下结果 −

A custom exception is being thrown here...
Now inside the Finally Block